Netzwerklaufwerke beim Login verbinden

Methode 1 - AppleScript

Um Netzwerklaufwerke zu verbinden kann ein kleines und sehr übersichtliches AppleScript eingesetzt werden.
Hierbei kann auch zwischen dem reinen Verbinden und dem Verbinden und öffnen unterschieden werden.
Der AppleScript Editor ist unter Programme → Dienstprogramme → AppleScript-Editor zu finden. Hier einfach folgendes Script einfügen und den eigenen Bedürfnissen anpassen:

try
	tell application "Finder"
		#Share verbinden
		mount volume "smb://path/to/share"
 
		#Share verbinden und öffnen
		open location "smb://path/to/share"
	end tell
end try

Nun das Script mit cmd + S speichern. Hier kann zwischen Skript und Programm unterschieden werden. Wird das Script als Skript gespeichert, ist der Startdialog zwingend erforderlich und kann nicht abgewählt werden. Dieser Startdialog frägt erneut ab, ob das Script wirklich ausgeführt werden soll. Wird das Script hingegen als Programm gespeichert, so ist dieser optional.
Als dritte Möglichkeit zur Speicherung kann das Script als geschütztes Programm gespeichert werden. Hier kann das Script NICHT erneut ausgelesen werden und sollte zur Sicherheit oder späteren Bearbeitung, zusätzlich als Script gespeichert werden. Um das Script als geschütztes Programm zu exportieren, muss im AppleScript-Editor, unter Ablage die Option Exportieren … gewählt werden. Hier wird als Dateiformat, wie bisher, Programm gewählt. Nun kann zusätzlich die Option Nur ausführbar ausgewählt werden. Nun ist das Script nicht mehr aus dem Programm auslesbar.


Weitere Beispiele

# Mit Benutzername und Passwort
mount volume "afp://user:passwort@192.168.2.3/Volume"
mount volume "afp://xxx.xxx.xxx.xx/Akzidenz" as user name "abc" with password "abc"
 
# Ohne Benutzername und Passwort
mount volume "afp://xxx.xxx.xxx.xx/Akzidenz_2" as user name "" with password ""
 
# Freigegebene Ordner auf einem Mac Mounten
mount volume "afp:/at/Mac03/• Leonardo Eingang" as user name "leonardo" with password "leonardo"
mount volume "afp:/at/Mac03/• Leonardo Ausgang" as user name "" with password ""


Methode 2 - Anmeldeobjekte

Um die, vom Systembereitgestellte, Möglichkeit der Anmeldeobjekte zu nutzen, muss das Laufwerk zuerst manuell verbinden werden. Nun in den Systemeinstellungen nach Benutzer & Gruppen navigiert werden. Hier, falls als Systemadministrator eingeloggt, den fraglichen Nutzer auswählen und unter Anmeldeobjekte wechseln. Um nun ein Objekt hinzuzufügen muss auf + geklickt werden. Hier nun das Laufwerk auswählen, das beim Start verbunden werden soll. Nun noch auf Hinzufügen klicken und die Share ist hinzugefügt.
Wurde das Laufwerk korrekt hinzugefügt, taucht es nun in der Liste, in der Spalte Art als Volume auf.
Hierbei sollte beachtet werden, das sich alle Laufwerke, die über diese Methode verbunden werden, beim Login sofort öffnen.


Methode 3 - Kombination

Sollen manche Laufwerke nur verbunden werden, manche aber direkt geöffnet werden, so bietet sich eine Kombination aus den beiden vorherigen Möglichkeiten an. Hier kann ein AppleScript, wie in Methode 1 beschrieben erstellt und als Anmeldeobjekt geladen werden. Nun können die Einstellungen der Laufwerke in der AppleScript-Datei angepasst werden. Diese Methode ist am flexibelsten. Hier besteht allerdings die Gefahr, das die Script-Datei versehentlich gelöscht wird. Diese sollte entsprechend abgelegt werden um das Risiko der Löschung zu vermeiden. Weiterhin kann das Script logischerweise nicht auf einer Share abgelegt werden, die durch das Script verbunden werden soll.
Ein geeigneter Speicherort wäre zum Beispiel: Users/<Username>/Library/Scripts


Script

Ein komplexes Script zum verbinden von beliebig vielen Laufwerken.

-- Script Version:	1.0
-- Script Autor:	Stefan Mueller
-- Script Hoomepage:	stefm.de
-- ABSOLUTE NO WARRANTY FOR ANYTHING!
 
 
 
 
tell application "Finder"
	#Share verbinden
	set fails to 0
	set tempError to 0
	-- Namen der Laufwerken, muessen den Volumes entsprechen
	set volNames to {"Dokumente", "Multimedia", "Filme", "softwareRepo", "Bilder"}
	set volPath to {"smb://path/vol1", "smb://path/vol2", "smb://path/vol3", "smb://path/vol4", "smb://path/vol5"}
 
	-- Testen ob kritische Fehler bei der Auflistung der Laufwerke gemacht wurden. Wenn ja abbrechen
	if not (length of volNames = length of volPath) then
		display dialog "Die Anzahl der Laufwerke entspricht nicht der Anzahl der Namen. Bitte verbessern!" buttons {"Script abbrechen"} default button 1
	else
 
		-- Anzahl der Volumes zaehlen
		set listLength to the length of volNames
 
		set loopVar to 1
		repeat while loopVar < listLength + 1
			-- Prüfen ob Laufwerk bereits verbunden ist
			set tempName to item loopVar of volNames
			if exists disk tempName then
				-- optional
				-- display dialog "Bereits verbunden" buttons {"Okay"} default button 1
			else
				-- Laufwerk verbinden
				set laufwerk to item loopVar of volPath
				repeat 5 times
					try
						mount volume laufwerk
					on error
						set tempError to tempError + 1
 
						-- vor naechstem Versuch 2 Sekunden warten
						delay 2
					end try
				end repeat
			end if
 
			-- Fehler zaehlen
			if (tempError > 0) then
				set fails to fails + 1
				set tempError to 0
			end if
 
			-- Schleifenvariable erhoehen
			set loopVar to loopVar + 1
 
			-- vor naechstem Laufwerk 2 Sekunden warten(optional)
			--delay 2
		end repeat
 
		-- Ausgabe der Anzahl der Fehler, wenn welche aufgetreten sind
		if fails > 0 then
			display dialog "Es gab " & fails & " Fehler. Die entsprechenden Laufwerke wurden nicht verbunden." buttons {"Okay"} default button 1
		end if
	end if
 
end tell



Weiteres: http://hohabadu.de/?APPLESCRIPT/Erkl%E4rende-Scripts/Netzwerk-Laufwerke-%2F-Volumes-mounten


mac/netzwerklaufwerke_beim_anmelden_verbinden.txt · Zuletzt geändert: 2015/07/06 22:32 (Externe Bearbeitung)