Windows-Rechner Remote herunterfahren

Windows source

Nur möglich, wenn der ausführende Benutzer Administrationsberechtigungen hat.

Möglichkeit 1 - GUI

Zeigt eine GUI an

shutdown -i


Möglichkeit 2 - Konsole

Hilfeseite shutdown

C:\>shutdown -?
Syntax: shutdown [-l | -s | -r | -a]  [-f]  [-m \\Computer]  [-t xx]  [-c "Kommentar"]  [-d up:xx:yy]

  Keine Argumente Zeigt diese Meldung an (wie -?).
  -i              Zeigt eine grafische Benutzeroberfläche an (muss die erste Option sein).

  -l              Abmelden (kann nicht mit der Option -m verwendet werden).
  -s              Fährt den Computer herunter.
  -r              Fährt den Computer herunter und startet ihn neu.
  -a              Bricht das Herunterfahren des Systems ab.

  -m \\Computer   Remotecomputer zum Herunterfahren/Neustarten/Abbrechen.
  -t xx           Zeitlimit für das Herunterfahren, in xx Sekunden.
  -c "Kommentar"  Kommentar für das Herunterfahren (maximal 127 Zeichen).
  -f              Erzwingt das Schließen ausgeführter Anwendungen ohne Warnung.
  -d [u][p]:xx:yy Grund (Code) für das Herunterfahren:
                  u = Benutzercode
                  p = Code für geplantes Herunterfahren
                  xx = Hauptgrund (positive ganze Zahl kleiner als 256)
                  yy = Weiterer Grund (positive ganze Zahl kleiner als 65536)


Beispiel

HERUNTERFAHREN - Rechner "winxp" in 30sec herunterfahren und die Nachricht "Shutting down for maintenance." anzeigen 
     shutdown /s /m \\winxp /t 30 /c "Shutting down for maintenance." /d P:1:1
     
NEUSTART -       Rechner "winxp" in 30sec neustarten     und die Nachricht "Restarting    for maintenance." anzeigen 
     shutdown /r /m \\winxp /t 30 /c "Restarting for maintenance." /d P:1:1
     
AUSLOGGEN - funktioniert nur lokal
     shutdown /l /t 30 /c "Logging off for maintenance." /d P:1:1
     
ABORT
     shutdown /a /m \\winxp


Möglichkeit 3 - Script

@echo off
COLOR 0C
title REMOTE SHUTDOWN - V1.0
 
:START
@echo.
@echo   *************************************************** 
@echo  *                                                   *
@echo  *              REMOTE SHUTDOWN - V1.0               *
@echo  *                                                   *
@echo  *                                                   *
@echo  *                           (C) 2013 Stefan Mueller *
@echo   *************************************************** 
@echo         %date% %time:~0,8%   %username%@%computername%
@echo.
@
set /P Target=Target DNSname: 
set /P Type=Type (shutdown / reboot / abort): 
 
:: Only ask if NOT 'abort'
IF NOT "%Type%" == "abort" (
set /P Time=Time in sec.: 
set /P Comment=Comment: 
)
 
 
:: Reboot Type Replacement
IF "%Type%" == "shutdown" set Type=s
 
IF "%Type%" == "reboot" set Type=r
 
IF "%Type%" == "abort" set Type=a
 
 
:: Short Type only on 'abort'
IF "%Type%" == "a" (
	shutdown /a /m \\%Target%
	@echo Executing...
	ping -n 2 127.0.0.1 > NUL
) ELSE (
	shutdown /%Type% /m \\%Target% /t %Time% /c "%Comment%" /d P:1:1
	@echo Executing...
	ping -n 2 127.0.0.1 > NUL
)
 
@echo.
@echo MENU
@echo  (1) Repeat script
@echo  (2) Abort shutdown
@echo  (3) Exit script
 
set /P Menu=Next step: 
 
IF "%Menu%" == "1" (
	cls
	GOTO START
)
 
IF "%Menu%" == "2" (
	shutdown /a /m \\%Target%
	cls
	GOTO START
)
 
IF "%Menu%" == "3" pause


UNIX source


windows/remote_shutdown.txt · Zuletzt geändert: 2015/07/06 22:33 (Externe Bearbeitung)